WIN10/11 注册表、批处理：屏蔽“同意个人数据跨境传输”

前言：

新版的WIN0和WIN11在安装的时候会出现“同意个人数据跨境传输”的提示，我们在定制和封装系统时，希望能屏蔽这个提示。

Win10的“同意个人数据跨境传输”提示

Win11的“同意个人数据跨境传输”提示

场景一（封装前在系统下导入或添加到部署中任务）：

注册表代码：

Windows Registry Editor Version 5.00
;屏蔽“同意个人数据跨境传输”，适合封装前在系统下导入注册表或使用第三方软件离线注入注册表。
[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport]
"PDEShown"=dword:00000002
[HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport]
"PDEShown"=dword:00000002

批处理代码：

@echo off
::屏蔽“同意个人数据跨境传输”，适合封装前在系统下导入或添加到部署中任务，同时支持封装版和安装版系统。
if exist %USERPROFILE%\NTUSER.DAT (
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport" /f /v "PDEShown" /t REG_DWORD /d 2
)
if exist %SystemDrive%\Users\Default\NTUSER.DAT (
reg add "HKU\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport" /f /v "PDEShown" /t REG_DWORD /d 2
)

场景二（封装后在WINPE离线注入再重新保存映像）：

注册表代码：

Windows Registry Editor Version 5.00
;屏蔽“同意个人数据跨境传输”，适合封装后在PE下离线注入。
;使用方法：先在WINPE下把系统映像安装到C盘，然后把“C:\Users\Default\NTUSER.DAT”加载配置单元到“HKEY_USERS\DF”，把“C:\Users\Administrator\NTUSER.DAT”加载配置单元到“HKEY_USERS\Administrator”，导入本注册表，卸载配置单元“HKEY_USERS\Default”和“HKEY_USERS\Administrator”，再重新打包系统映像。
[HKEY_USERS\Default\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport]
"PDEShown"=dword:00000002
[HKEY_USERS\Administrator\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport]
"PDEShown"=dword:00000002

批处理代码：

@echo off
echo.
echo 屏蔽“同意个人数据跨境传输”的提示，操作步骤：
echo.
echo 1.先在WINPE下把系统映像安装到C盘
echo.
::设置系统所在分区
SET sysdrv=C
echo （注意：安装分区如果不是C盘，请修改上面 sysdrv 变量的值）
echo.
echo 2.然后点任意键继续离线注入注册表
pause 1 >nul
echo.
FOR /D %%i IN (%sysdrv%:\Users\*) DO (
IF NOT %%i == %sysdrv%:\Users\Public echo 开始注入：%%i\NTUSER.DAT &echo.
IF EXIST %%i\NTUSER.DAT (
REG LOAD HKU\UXPC %%i\NTUSER.DAT &echo.
REG ADD "HKU\UXPC\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport" /f /v "PDEShown" /t REG_DWORD /d 2 &echo.
REG UNLOAD HKU\UXPC &echo.
)
)
echo 开始注入：%sysdrv%:\Users\Default\NTUSER.DAT &echo.
if exist %sysdrv%:\Users\Default\NTUSER.DAT (
REG LOAD HKU\UXPC %sysdrv%:\Users\Default\NTUSER.DAT &echo.
REG ADD "HKU\UXPC\Software\Microsoft\Windows\CurrentVersion\CloudExperienceHost\Intent\PersonalDataExport" /f /v "PDEShown" /t REG_DWORD /d 2 &echo.
REG UNLOAD HKU\UXPC &echo.
)
echo 3.离线设置完成，任意键退出，重新打包系统映像即可。
pause 1 >nul

注册表说明：

• PDEShown 键值为1：显示
• PDEShown 键值为2：隐藏
• 但注意早期2023年7月前的版本的WIN10/11键值是相反的，需要把2改成1。
• 保存注册表文件和批处理文件时，注意选择“ANSI”文件编码。
• 四个代码作用都一样，按实际使用场景选其中一个即可。

适用系统：

• WIN10：已测试
• WIN11：已测试